imported from "final" folder

.pio/libdeps/esp01_1m/ArtnetWifi/examples/ArtnetWifiNeoPixel/ArtnetWifiNeoPixel.ino

@@ -0,0 +1,141 @@
+/*
+This example will receive multiple universes via Artnet and control a strip of ws2811 leds via 
+Adafruit's NeoPixel library: https://github.com/adafruit/Adafruit_NeoPixel
+This example may be copied under the terms of the MIT license, see the LICENSE file for details
+*/
+#include <ArtnetWifi.h>
+#include <Arduino.h>
+#include <Adafruit_NeoPixel.h>
+
+//Wifi settings
+const char* ssid = "ssid";
+const char* password = "pAsSwOrD";
+
+// Neopixel settings
+const int numLeds = 240; // change for your setup
+const int numberOfChannels = numLeds * 3; // Total number of channels you want to receive (1 led = 3 channels)
+const byte dataPin = 2;
+Adafruit_NeoPixel leds = Adafruit_NeoPixel(numLeds, dataPin, NEO_GRB + NEO_KHZ800);
+
+// Artnet settings
+ArtnetWifi artnet;
+const int startUniverse = 0; // CHANGE FOR YOUR SETUP most software this is 1, some software send out artnet first universe as 0.
+
+// Check if we got all universes
+const int maxUniverses = numberOfChannels / 512 + ((numberOfChannels % 512) ? 1 : 0);
+bool universesReceived[maxUniverses];
+bool sendFrame = 1;
+int previousDataLength = 0;
+
+// connect to wifi – returns true if successful or false if not
+bool ConnectWifi(void)
+{
+  bool state = true;
+  int i = 0;
+
+  WiFi.begin(ssid, password);
+  Serial.println("");
+  Serial.println("Connecting to WiFi");
+  
+  // Wait for connection
+  Serial.print("Connecting");
+  while (WiFi.status() != WL_CONNECTED) {
+    delay(500);
+    Serial.print(".");
+    if (i > 20){
+      state = false;
+      break;
+    }
+    i++;
+  }
+  if (state){
+    Serial.println("");
+    Serial.print("Connected to ");
+    Serial.println(ssid);
+    Serial.print("IP address: ");
+    Serial.println(WiFi.localIP());
+  } else {
+    Serial.println("");
+    Serial.println("Connection failed.");
+  }
+  
+  return state;
+}
+
+void initTest()
+{
+  for (int i = 0 ; i < numLeds ; i++)
+    leds.setPixelColor(i, 127, 0, 0);
+  leds.show();
+  delay(500);
+  for (int i = 0 ; i < numLeds ; i++)
+    leds.setPixelColor(i, 0, 127, 0);
+  leds.show();
+  delay(500);
+  for (int i = 0 ; i < numLeds ; i++)
+    leds.setPixelColor(i, 0, 0, 127);
+  leds.show();
+  delay(500);
+  for (int i = 0 ; i < numLeds ; i++)
+    leds.setPixelColor(i, 0, 0, 0);
+  leds.show();
+}
+
+void onDmxFrame(uint16_t universe, uint16_t length, uint8_t sequence, uint8_t* data)
+{
+  sendFrame = 1;
+  // set brightness of the whole strip 
+  if (universe == 15)
+  {
+    leds.setBrightness(data[0]);
+    leds.show();
+  }
+
+  // Store which universe has got in
+  if ((universe - startUniverse) < maxUniverses)
+    universesReceived[universe - startUniverse] = 1;
+
+  for (int i = 0 ; i < maxUniverses ; i++)
+  {
+    if (universesReceived[i] == 0)
+    {
+      //Serial.println("Broke");
+      sendFrame = 0;
+      break;
+    }
+  }
+
+  // read universe and put into the right part of the display buffer
+  for (int i = 0; i < length / 3; i++)
+  {
+    int led = i + (universe - startUniverse) * (previousDataLength / 3);
+    if (led < numLeds)
+      leds.setPixelColor(led, data[i * 3], data[i * 3 + 1], data[i * 3 + 2]);
+  }
+  previousDataLength = length;     
+  
+  if (sendFrame)
+  {
+    leds.show();
+    // Reset universeReceived to 0
+    memset(universesReceived, 0, maxUniverses);
+  }
+}
+
+void setup()
+{
+  Serial.begin(115200);
+  ConnectWifi();
+  artnet.begin();
+  leds.begin();
+  initTest();
+
+  // this will be called for each packet received
+  artnet.setArtDmxCallback(onDmxFrame);
+}
+
+void loop()
+{
+  // we call the read function inside the loop
+  artnet.read();
+}